root/websites/jwatch.jp/trunk/misc/load_schedule_from_jsgoal.pl @ 11332

#!/usr/bin/perl
use strict;
use warnings;
use utf8;

use FindBin;
use Web::Scraper;
use DateTime;
use DateTime::Format::Strptime;
use YAML;
use URI;
use URI::QueryParam;
use lib "$FindBin::Bin/../lib";
use JWatch::ConfigLoader;
use JWatch::Schema;

my $config = JWatch::ConfigLoader->load;
my $schema = JWatch::Schema->connect(
    @{$config->{'Model::DBIC'}->{connect_info}}
);
my $clubs = $schema->resultset('Club');
my $games = $schema->resultset('Game');
my $events = $schema->resultset('Event');

my $gamecount = $games->search_literal(
    'now() > kickoff and '.
    'now() < date_add(kickoff, interval 3 hour)'
);
$gamecount > 0 or exit 0;

my $baseurl = 'http://www.jsgoal.jp';
my $strp = DateTime::Format::Strptime->new(
    pattern => '%Y年%m月%d日（%a） %H:%Mキックオフ',
    time_zone => 'Asia/Tokyo',
    locale => 'ja',
);
my $scraper = scraper {
    process '//table[@id="scheduletable"]/tr', 'game[]' => \&schedule_row;
    result 'game';
};

for my $uri (qw(
    /schedule/2008/j1.html
    /schedule/2008/j2.html
)) {
    for my $game (@{$scraper->scrape(URI->new_abs($uri, $baseurl))}) {
        my $found = $games->find({id => $game->{id}});
        if ($found) {
            if (! defined $found->score_home && defined $game->{score_home}) {
                $events->create({
                        gameid => $game->{id},
                        type => 'end',
                        datetime => DateTime->now(time_zone => 'Asia/Tokyo'),
                    });
            }
            $found->update($game);
        } else {
            $games->create($game);
        }
    }
}

my $gameno;
sub schedule_row {
    my $row = shift;
    if (my $game = $row->look_down(_tag => 'td', class => 'term')) {
        ($gameno) = $game->as_text =~ m{第(\d+)節};
        return;
    }
    $row->look_down(_tag => 'td', class => 'exp') and return;
    my @cell = $row->look_down(_tag => 'td');
    my $gameurl = $cell[2]->look_down(_tag => 'a') or return;
    $gameurl = $gameurl->attr('href') or return;
    my ($gameid, $category) = $gameurl =~ m{^/game/\d{4}/(\d{4}(\d{2})\d+).html$};
    my ($score_home, $score_away) = $cell[2]->as_text =~ m{(\d+)-(\d+)};
    my $kickoff = scraper {
        process 'div.time', 'kickoff' => 'TEXT';
        result 'kickoff';
    }->scrape(URI->new_abs($gameurl, $baseurl));
    $kickoff = $strp->parse_datetime($kickoff);
    my $clubid_home = $clubs->find({shortname => $cell[1]->as_text})->id;
    my $clubid_away = $clubs->find({shortname => $cell[3]->as_text})->id;
    my $stadiumlink = $cell[4]->look_down(_tag => 'a');
    my $stadiumid = URI->new($stadiumlink->attr('href'))->query_param('s') if $stadiumlink;
    return {
        id => $gameid || '',
        category => $category,
        gameno => $gameno,
        kickoff => $kickoff || '',
        clubid_home => $clubid_home,
        clubid_away => $clubid_away,
        stadiumid => $stadiumid || 0,
        score_home => defined $score_home ? $score_home : undef,
        score_away => defined $score_away ? $score_away : undef,
    };
}