root/websites/jwatch.jp/trunk/misc/update_game_from_jsgoal.pl @ 11386

#!/usr/bin/perl
use strict;
use warnings;
use utf8;
use FindBin;
use YAML;
use URI;
use DateTime;
use DateTime::Format::MySQL;
use DateTime::Format::Strptime;
use Web::Scraper;
use lib "$FindBin::Bin/../lib";
use JWatch::ConfigLoader;
use JWatch::Schema;

my $config = JWatch::ConfigLoader->load;
my $schema = JWatch::Schema->connect(
    @{$config->{'Model::DBIC'}->{connect_info}}
);
my $games = $schema->resultset('Game');
my $events = $schema->resultset('Event');
my $game_players = $schema->resultset('GamePlayer');
my $players = $schema->resultset('Player');
my $game_officials = $schema->resultset('GameOfficial');
my $officials = $schema->resultset('Official');

my $scraper = scraper {
    process '//tr[td[4]="先発"]/parent::table/tr', 'players[]' => \&get_players;
    process '//tr[td[1]="試合経過"]/following-sibling::tr', 'events[]' => \&get_events;
    process '//tr[td[1]="主審"]/parent::table/tr', 'officials[]' => \&get_officials;
};
my ($game,$gameid,$kickoff,$type,$playerhash);

for ($games->search_literal('now() > date_sub(kickoff, interval 3 hour) and now() < date_add(kickoff, interval 3 hour)')) {
    $game = $_;
    $gameid = $game->id;
    (my $gameid_short = $gameid) =~ s{\d{8}$}{};
    $kickoff = $game->kickoff;
    my $uri = URI->new(
        'http://www.jsgoal.jp/score/board/'.
        join('/', $kickoff->year, $kickoff->strftime("%m%d"), $gameid_short).
        '_stats.html'
    );
    my $res = eval {$scraper->scrape($uri)};
    $@ and warn $@ and next;
    unless ($events->find({ gameid => $gameid, type => 'member' })) {
        for (@{$res->{players}}) {
            $game_players->find_or_create($_);
        }
        for (@{$res->{officials}}) {
            $game_officials->find_or_create($_);
        }
        if ($#{$res->{officials}} > 0 && $#{$res->{players}} > 0 ) {
            $events->find_or_create({
                    gameid => $gameid,
                    type => 'member',
                    datetime => DateTime->now(time_zone => 'local'),
                });
        }
    }
    for (@{$res->{events}}) {
        $events->find($_) and next;
        $_->{datetime} = DateTime->now(time_zone => 'local');
        $events->create($_);
    }
}

sub get_players {
    my @cell = $_->look_down(_tag => 'td');
    if ($#cell == 6) {
        $type = $cell[3]->as_text eq '先発' ? 'starter' : 'reserve';
    } elsif ($#cell == 2) {
        return;
    }
    $cell[0]->as_text eq 'Pos' and return;
    $playerhash->{$game->clubid_home}->{$cell[2]->as_text} = $cell[1]->as_text;
    $playerhash->{$game->clubid_away}->{$cell[-1]->as_text} = $cell[-2]->as_text;
    return (
        {
            gameid => $gameid,
            clubid => $game->clubid_home,
            position => $cell[0]->as_text,
            number => $cell[1]->as_text,
            type => $type,
        },
        {
            gameid => $gameid,
            clubid => $game->clubid_away,
            position => $cell[-3]->as_text,
            number => $cell[-2]->as_text,
            type => $type,
        }
    );
}

sub get_events {
    my @cell = $_->look_down(_tag => 'td');
    my ($gametime, $clubid);
    if ($cell[1]->as_text =~ /^(\D+)(\d+)?/) {
        if ($1 eq '前半') {
            $gametime = $2;
        } elsif ($1 eq '後半') {
            $gametime = $2 + 45;
        } elsif ($1 eq 'ﾊｰﾌﾀｲﾑ') {
            $gametime = 45;
        } elsif ($1 eq '試合終了') {
            $gametime = 90;
        }
    }
    my $needcell;
    if (length($cell[0]->as_trimmed_text) > 1) {
        $clubid = $game->clubid_home;
        $needcell = 0;
    } else {
        $clubid = $game->clubid_away;
        $needcell = 2;
    }
    my %event = &process_event($cell[$needcell], $clubid);
    %event = (%event, 
        gameid => $gameid,
        gametime => $gametime,
        clubid => $clubid,
    );
    
    return \%event;
}

sub process_event {
    my ($elem,$clubid) = @_;
    my ($player1, $player2, $description);
    my $img = $elem->look_down(_tag => 'img') or return ();
    my ($eventtype) = $img->attr('src') =~ /_(.+)\./;
    ($player1 = $elem->as_trimmed_text) =~ s{^\s+|\s+$}{}g;
    if ($eventtype eq 'change') {
        ($player1, $player2) = $player1 =~ /(.+)\s→\s(.+)/;
        $player2 = $playerhash->{$clubid}->{$player2} || '';
        warn "player2 not found:", $elem->as_text, ", clubid:", $clubid, ", gameid:", $gameid unless $player2;
    } elsif ($eventtype eq 'other') {
        $description = $elem->as_trimmed_text;
    }
    if ($player1 eq 'オウンゴール') {
        $description = 'own goal';
        $player1 = '';
    } else {
        $player1 = $playerhash->{$clubid}->{$player1} || '';
        warn "player1 not found:", $elem->as_text, ", clubid:", $clubid, ", gameid:", $gameid unless $player1;
    }
    return (
        player1 => $player1 || 0,
        player2 => $player2 || 0,
        type    => $eventtype || 'other',
        description => $description || '',
    );
}

sub get_officials {
    my @cell = $_->look_down(_tag => 'td');
    $type = ($cell[0]->as_text eq '主審') ? 'referee' : 'assistant';
    my $official = $officials->search_literal("replace(name, '　','') = ?", $cell[-1]->as_text)->next or return;
    return {
        gameid => $gameid,
        type => $type,
        officialid => $official->id,
    }
}