root/websites/mobilecat/trunk/lib/MobileCat/Base/MobileAuth.pm

package MobileCat::Base::MobileAuth;
use strict;
use warnings;
use base qw/ Catalyst::Controller Catalyst::Component::ACCEPT_CONTEXT /;
__PACKAGE__->mk_accessors(qw( cidr ));

use Net::CIDR::MobileJP;

sub new {
    my $self = shift->next::method(@_);
    
    $self->config({
        check_ua        => 1,
        check_ip        => 1,
        error_stash_key => 'auth_error',
        %$self,
    });
    
    $self->cidr( Net::CIDR::MobileJP->new ) if $self->config->{check_ip};
    
    $self;
}

sub confirm_mobile :Private {
    my ($self) = @_;
    
    if ($self->config->{check_ua} &&
        $self->context->req->mobile_agent->is_non_mobile) {
        $self->_failed('user_agent is non_mobile');
        return;
    }
    
    if ($self->config->{check_ip} &&
        $self->cidr->get_carrier($self->context->req->address) eq 'N') {
        $self->_failed('invalid mobile ip');
        return;
    }
    
    if (not eval { $self->context->req->mobile_agent->user_id }) {
        $self->_failed('mobile_id required');
        return;
    }
    
    return 1;
}

sub authenticate_mobileid :Private {
    my ($self, $authinfo) = @_;
    
    return unless $self->confirm_mobile;
     
    $self->context->logout;
    
    $authinfo ||= {};
    $authinfo->{username} = $self->context->req->mobile_agent->user_id;
    
    if (my $user = $self->context->authenticate($authinfo)) {
        return $user;
    } else {
        $self->_failed('login failed');
        return;
    }
}

sub _failed {
    my ($self, $reason) = @_;
    
    $self->context->log->debug('Failed to authenticate MobileID. Reason:'. $reason);
    
    $self->context->stash->{ $self->config->{error_stash_key} } = $reason
        if $self->config->{error_stash_key};
}

1;