root/websites/mobilecat/trunk/lib/MobileCat/Controller/API/Mail/Post.pm

package MobileCat::Controller::API::Mail::Post;
use strict;
use warnings;
use base 'Catalyst::Controller';

use Email::MIME;
use Email::MIME::XPath;
use Encode::JP::Mobile;

sub index :Private {
    my ($self, $c) = @_;
    my ($action, $secret) = split /\W/, $c->req->param('rcpt') || "";
    
    my $user = $c->model('Users')->single({
        username  => { '!=', undef },
        email     => $c->req->params->{sender},
        secret    => $secret,
    });
    
    return unless $user;
    
    my $email = Email::MIME->new($c->req->param('source'));
    my ($part) = $email->xpath_findnodes('//plain');
    
    return unless $part;
    
    my $carrier = Email::Address::JP::Mobile->new($c->req->param('from'));
    
    my $text = do {
        my $carrier = $carrier->name eq 'EZweb' ? 'ezweb-auto' : $carrier->name;
        my $charset = $part->{ct}{attributes}{charset};
        my $encoding = Encode::find_encoding("x-$charset-$carrier");
        if ($encoding) {
            $encoding->decode($part->body);
        } else {
            Encode::decode('iso-2022-jp', $part->body);
        }
    };

    $c->user($user);
    $c->req->param(filter => 1);
    $c->req->param(body   => $text);
    $c->forward('/entry/create');
}

1;