root/websites/mobilecat/trunk/lib/MobileCat/Controller/Signup.pm

package MobileCat::Controller::Signup;
use strict;
use warnings;
use base 'Catalyst::Controller';

sub index :Private {
    my ($self, $c) = @_;
    $c->view('TT')->template('signup/index.tt');
}

sub entry :Local {
    my ($self, $c) = @_;
    
    if ($c->forward('/auth/authenticate_mobileid')) {
        $c->stash->{error} = 'already exists';
        return;
    }
    
    if (not $c->forward('/auth/confirm_mobile')) {
        $c->stash->{error} = $c->stash->{auth_error} || 'unknown';
        return;
    }
    
    $c->forward('create');
}

sub create :Private {
    my ($self, $c) = @_;
    
    my $user = $c->model('Users')->create({
        username  => undef,
        mobile_id => $c->req->mobile_agent->user_id,
    });
    
    $c->stash->{ticket} = $c->model('Tickets')->create({
        action  => 'signup',
        user_id => $user->id,
    });
}

sub welcome :Private {
    my ($self, $c) = @_;
    
    my $user = $c->stash->{ticket}->user;
    $c->req->param(username => $user->mobile_id);
    $c->req->param(email    => $c->req->param('sender'));
    $c->form(
        username => [ 'NOT_BLANK' ],
        email    => [ 'NOT_BLANK', 'EMAIL_MOBILE_JP' ],
    );
    
    if ($c->form->has_error) {
        return;
    }
    if ($user->enable($c->form->valid)) {
        $c->view('Email')->send('mail/welcome.tt', {
            to => $user->email,
        });
    } else {
        $c->log->error('user enable error. user_id:'. $user->id);
    }
}

1;