root/websites/mobilecat/trunk/lib/MobileCat/View/Email.pm

package MobileCat::View::Email;
use strict;
use warnings;
use base qw/ Catalyst::View Catalyst::Component::ACCEPT_CONTEXT /;
__PACKAGE__->mk_accessors(qw/ mailer /);

use Carp;
use Email::Address::JP::Mobile;
use Email::MIME;
use Email::MIME::Creator;
use Email::Send ();

sub new {
    my $self = shift->next::method(@_);
    
    $self->mailer( Email::Send->new($self->{sender}) );
    $self;
}

sub send {
    my ($self, $template, $args) = @_;
    
    $args = $self->merge_config_hashes(
        $self->{default},
        $args || {}
    );
    
    $self->context->stash(set_subject => sub { # capture subject
        $args->{subject} = shift if $_[0];
        return;
    });
     
    $args->{body} ||= $self->context->view('TT')->render($template);
    
    my $carrier = Email::Address::JP::Mobile->new($args->{to})
        or croak "'to' isnt defined!";
    
    my $header = [];
    for my $field (qw( To From Bcc Cc Subject )) {
        next unless $args->{ lc $field };
        
        if ($field eq 'Subject') {
            $args->{ lc $field } = $carrier->mime_encoding->encode($args->{ lc $field });
        } else {
            $args->{ lc $field } = Encode::encode_utf8($args->{ lc $field }); # = utf8_off
        }
        
        push @$header, ( $field => $args->{ lc $field } );
    }
    
    my $email = Email::MIME->create(
        header     => $header,
        attributes => {
            content_type => 'text/plain',
            charset      => $carrier->mail_encoding->mime_name,
        },
        body => $carrier->mail_encoding->encode($args->{body}),
    );

    $self->context->log->debug($email->as_string);
    
    my $return = $self->mailer->send($email);
    croak "$return" if ! $return;
}

1;