root/websites/showa_photo_generator/showanize.pl @ 282

#!/usr/bin/perl
# -*- coding:utf-8 -*-
#
# Author: FUJIWARA Shunichiro <fujiwara.shunichiro at gmail.com>
# License: Same as Perl
#

use strict;
use Imager;
use Imager::Fill;
use Imager::Font;
use List::Util qw/ min max /;
use Getopt::Long;

my ( $date, $usage );
GetOptions(
    "date=s"     => \$date,
    "help|usage" => \$usage,
);
my ( $source_file, $result_file ) = @ARGV;

if ( !defined $source_file || !defined $result_file || $usage ) {
    usage();
}

my $img = Imager->new;
$img->read( file => $source_file )
    or die $img->errstr;

$img->filter( type => "contrast", intensity => 0.7 );
$img->filter( type => "conv", coef => [ 0, 1, 0.2 ] );
$img = solid_border( $img, "#bbbbbb" );

my $fill = Imager::Fill->new( solid => random_color('413626'), combine => 'add' );
$img->box( fill => $fill );

$img = add_date( $img, $date ) if $date;

$img->filter(
    type    => 'noise',
    amount  => 10,
    subtype => 1,
);

$img->write( file => $result_file, type => 'jpeg' )
    or die $img->errstr;

# solid_border is based on Imager/samples/border.pl
# http://search.cpan.org/~tonyc/Imager/samples/border.pl
sub solid_border {
  my ( $source, $color ) = @_;

  my $w = $source->getwidth();
  my $h = $source->getheight();
  my $border = int ( max( $w * 0.015, $h * 0.015, 5 ) );
  my $out = Imager->new(
      xsize    => $source->getwidth()  + 2 * $border,
      ysize    => $source->getheight() + 2 * $border,
      bits     => $source->bits,
      channels => $source->getchannels,
  );

  $out->box( filled => 1, color => $color )
    or die "Invalid color '$color':", $out->errstr, "\n";

  $out->paste(
      left => $border,
      top  => $border,
      img  => $source,
  );

  return $out;
}

sub random_color {
    my $code = shift;
    my @color = map { hex $_ } ( $code =~ m{(..)}g );

    for my $c ( @color ) {
        $c *= ( 1 + ( rand() > 0.5 ? +1 : -1 ) * rand(0.15) );
        $c = min( $c, 255 );
        $c = max( $c, 0   );
    }
    $code = sprintf('#%02x%02x%02x', @color);
    return $code;
}

sub add_date {
    my $img  = shift;
    my $date = shift;
    $date =~ s/[^ \d\-\.]//g;

    my $color  = Imager::Color->new('#ffaa33');
    my $ttfont = Imager::Font->new(
        file  => '7barPBd.TTF', # http://www.trojanbear.net/omake.htm#sevenbarb
    );
    my $size = int( ($img->getwidth + $img->getheight) * 0.02 );
    $img->align_string(
        font   => $ttfont,
        text   => $date,
        x      => int( $img->getwidth  - $size * 1.5 ),
        y      => int( $img->getheight - $size * 1.5 ),
        halign => 'right',
        valign => 'bottom',
        size   => $size,
        color  => $color,
        aa     => 1,
    );
    return $img;
}

sub usage {
    print <<_END_
Usage:
showanize.pl [ --date DATE_STRING ] SOURCE_FILE RESULT_FILE

_END_
;
    exit;
}